137
Part 4 – Saving a layer plus recalling data into a created layer before modifying.
SCL provides a number of excellent functions to create, add, import and manipulate layers. There is also great reference material in the Surpac->Help menu. My aim in this series is to introduce some of these features in more layman’s terms. Some knowledge of how macro’s work with variables and commands will certainly be helpful but is not essential.
In the following tip;
- My comments in the code blocks will have a # in front of them. They are also in bold and italicized.
- If you would like to test this code in Surpac, the entire code block (Including previous parts 1, 2 and 3) has been added to the end of the tip. Copy it into any text editor and save it with a .tcl extension to use it in Surpac. The final result will look similar (but not the same due to styles and the choices you make when using the macro) as the screen capture below.
The “puts” command will print the series number to the message window plus other information about what this macro will do.
puts "" puts "Part 4 - Saving a layer then recalling data into a created layer before modifying." # Saving a layer can be done with a normal recorded "Save Layer" or "Save File" function however SCL provides a way to do it as well. # Depending on which layer you chose in part 3 will depend on which layer will now be saved.
Using TCL “clock” command, extract the date in a format that we can use with a string file header. This information will be stored in the variable called “today”
# This will get the date into a format that the string file header can use set today [clock format [clock seconds] -format "%d %b %Y"]
Create an “options” variable that will essentially become the header record of the string file.
#Options variable is a set of parameters separated by the | symbol. Some of the options are styles, binary or text and string range. set options "header=$layer, $today, Test of SclSwaSaveStringFile, ssi_styles:styles.ssi|axis=0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0|binary=off"
Using the SclSwaSaveStringFile command, save the layer referenced by $ourSwa reference variable then exit graphics.
# This is the line of code that will save a string file with your included options.
$ourSwa SclSwaSaveStringFile $layer.str "$options"
# Let's assume we have saved the data we want and need to exit graphics to start another project.
SclFunction "EXIT GRAPHICS" {}
Recall your saved string file into a new layer called “new_design”
# Now, let's recall your saved string file into a new layer we will call new_design # Get a reference to the active viewport (You can have more than one) store it in reference variable "vh" SclGetActiveViewport vh # Create a layer called new_design that can be manipulated/inquired with the "newDesignSwa" reference variable SclCreateSwa newDesignSwa "new_design" # Add the new_design layer into the layers pane so it is visible sclGraphicsLayers SclAdd $newDesignSwa $vh # Everything in "" is an option. The option to "load draw styles" will ensure the styles file is used. $newDesignSwa SclSwaOpenFile $layer.str "load draw styles"
Set the “new_design” layer as the active layer then get a handle to all the strings before drawing them in graphics.
# Make the "new_design" layer active. $vh SclSetActiveLayer $newDesignSwa # Get a handle to all the strings in the new_design layer $newDesignSwa SclGetStrings newDesignStrs # Using the handle to all the strings contained in $newDesignStrs reference variable, draw all the strings in graphics $newDesignStrs SclDraw
Zoom to data extents
# Whenever you bring data into a layer, you'll generally need to zoom all to see it.
SclFunction "ZOOM ALL" {}
Using the SclSelectPoint command (inside a TCL while loop) to manipulate data. This is one of my favourite SCL commands in Surpac and is useful in so many situations.
# Now, lets say we wanted to edit a point in the layer to a known coordinate. We first need to get a "handle" to the point.
# We will use "SclSelectPoint" to achieve this. This is a very versatile function that I'll cover in a later QA doco.
# There are many options for editing this point however for this QA I will just move the point 1m East for every click on the point.
# To do this we need to put the command in a while loop.
while {1} {
# Note pointMod below. This is the reference variable that gives me complete access to this point and all data attached to it.
# Note also that the coordinates of the point are stored in the x, y and z variables below as well.
set status [SclSelectPoint pointMod "Click a point to move by 1m East. Press Esc to continue." layerName strNum segNum pntNum x y z desc]
Using the $pointMod handle we can use the SclGetParent command to gain access to the segment it belongs to. The handle to the segment is stored in the reference variable called “segMod”
# Using the handle we have to the point in reference variable "pointMod" get a handle to the segment it resides in. $pointMod SclGetParent segMod
We use a TCL if command to check that the user is still selecting points. As soon as they press “escape” the while loop is broken with the TCL “break” command.
if {$status != "$SCL_OK"} {
puts "Finished moving points"
break
}
We use the SclSetValueByName command to modify the x coordinate of the selected point. In our case we are just coding it so that 1m is added to the x value of any point we select.
# Add 1m to the current x value $pointMod SclSetValueByName x [expr $x+1]
Using the handle to the segment ($segMod) we erase the segment before redrawing it with the updated changes. The bracket just closes the while loop.
$segMod SclErase # Using the handle to the segment, draw the updated coords on the screen. $segMod SclDraw }
Some notes on part 5 of this series.
# At this point you could exit or save the modifications. We will leave the modified layer in graphics ready for Part 5 of this series. # Part 5 will cover how to use SCL to loop over all points in a layer.
Entire code block – Parts 1 to 4 – Copy into text editor and run in Surpac with .tcl extension
####### PART 1 #######
# Get a reference to the active viewport (You can have more than one) store it in reference variable "vh"
SclGetActiveViewport vh
# Using the "vh" reference, get the active layer and store the reference in the "initialSwa" variable
$vh SclGetActiveLayer initialSwa
# Extract the layer name into the layerName variable using the SCL command "SclGetId"
set layerName [$initialSwa SclGetId]
# Print the layer name to the message window
puts "Layer name is $layerName"
# Create a layer called design that can be manipulated/inquired with the "designSwa" reference variable
SclCreateSwa designSwa "design"
# Use the SclAdd function to add the layer into the layer panel
sclGraphicsLayers SclAdd $designSwa $vh
# Using the reference to "designSwa", create a reference variable "designStr" and make the string number 8
$designSwa SclCreateString designStr 8
# Using the reference to the "designStr" create a reference variable "designSeg" and count how many items (i.e. segments) already
# exist for string 8. If there are 5 existing segments in string number 8, [$designStr SclCountItems] will return a value of 5.
# 5 will become the new segment number. Now, why doesn't this clash with the existing segments if there are already 5 of them?
# This is because the segments are stored as an index position which starts at zero. i.e. segment 1 = index 0, segment 2 = index 1
# ... segment 5 = index 4 and so on.
# All of this to say that when we count how many items are in string 8, the number returned will work as the next index position
# which is what the "SclCreateSegment" function requires. So if I write it manually it becomes
# $designStr SclCreateSegment designSeg 5
$designStr SclCreateSegment designSeg [$designStr SclCountItems]
# Using the reference variable "designSeg" count how many points there are and add this one to the end
$designSeg SclCreatePoint designPnt [$designSeg SclCountItems]
$designPnt SclSetValueByName X 10
$designPnt SclSetValueByName Y 10
$designPnt SclSetValueByName Z 10
$designPnt SclSetValueByName d1 "Testing SCL layer commands"
# Using the reference variable "designSeg" count how many points there are and add this one to the end
$designSeg SclCreatePoint designPnt [$designSeg SclCountItems]
$designPnt SclSetValueByName X 10
$designPnt SclSetValueByName Y 20
$designPnt SclSetValueByName Z 10
# Using the reference variable "designSeg" count how many points there are and add this one to the end
$designSeg SclCreatePoint designPnt [$designSeg SclCountItems]
$designPnt SclSetValueByName X 20
$designPnt SclSetValueByName Y 20
$designPnt SclSetValueByName Z 10
# Using the reference variable "designSeg" count how many points there are and add this one to the end
$designSeg SclCreatePoint designPnt [$designSeg SclCountItems]
$designPnt SclSetValueByName X 20
$designPnt SclSetValueByName Y 10
$designPnt SclSetValueByName Z 10
# To close the shape, make the x,y and z the same as the first point.
$designSeg SclCreatePoint designPnt [$designSeg SclCountItems]
$designPnt SclSetValueByName X 10
$designPnt SclSetValueByName Y 10
$designPnt SclSetValueByName Z 10
# Using the reference to the design layer (designSwa), use the command "SclDraw" to draw everything in the design layer.
$designSwa SclDraw
SclFunction "ZOOM ALL" {}
# Now, the active layer is still the initial layer that was active when the macro was first run. Let's make it the design layer
$vh SclSetActiveLayer $designSwa
####### PART 2 #######
#Create a layer called square_2 that can be manipulated/inquired with the "square2Swa" reference variable
SclCreateSwa square2Swa "square_2"
sclGraphicsLayers SclAdd $square2Swa $vh
# Using the reference to "square2Swa", create a reference variable "square2Str" and make the string number 6
$square2Swa SclCreateString square2Str 6
# Create a new segment. See details from part 1 about how this works.
$square2Str SclCreateSegment square2Seg [$square2Str SclCountItems]
# Procedure is called "newPoint" and takes 4 parameters.
# 1. The segment reference 2. The X coord, 3. The Y coord and 4. the Z coord
proc newPoint {segHandle x y z} {
# The rest of the code is exactly the same as what we did in part one when creating a new point
# The only difference being that we are using variables i.e. $x that are input when the procedure is called.
$segHandle SclCreatePoint pntHandle [$segHandle SclCountItems]
$pntHandle SclSetValueByName X $x
$pntHandle SclSetValueByName Y $y
$pntHandle SclSetValueByName Z $z
return $pntHandle
}
newPoint $square2Seg 11 11 10;# First point, note that we are using square2seg as the segment reference
newPoint $square2Seg 11 19 10
newPoint $square2Seg 19 19 10
newPoint $square2Seg 19 11 10
newPoint $square2Seg 11 11 10;# Closing point is same as first point
# Create a layer called square_3 that can be manipulated/inquired with the "square3Swa" reference variable
SclCreateSwa square3Swa "square_3"
sclGraphicsLayers SclAdd $square3Swa $vh
# Using the reference to "square3Swa", create a reference variable "square3Str" and make the string number 9
$square3Swa SclCreateString square3Str 9
# See details from part 1 about how SclCreateSegment works.
$square3Str SclCreateSegment square3Seg [$square3Str SclCountItems]
newPoint $square3Seg 13 13 10;# First point, note that we are using square3seg as the segment reference
newPoint $square3Seg 13 17 10
newPoint $square3Seg 17 17 10
newPoint $square3Seg 17 13 10
newPoint $square3Seg 13 13 10;# Closing point is same as first point
$square2Str SclDraw
$square3Str SclDraw "style=ssi_method=line,HGS_color=line=red,HGS_line_weight=2"
####### PART 3 #######
puts ""
puts "Part 3 - layer iteration and finding the layer you want. Plus, creating a small GUIDO form."
# Get a handle to the active viewport and store it in reference variable "vh"
SclGetActiveViewport vh
# Use sclGraphicsLayers command with SclIterateFirst command to setup a layer iterator
sclGraphicsLayers SclIterateFirst Iterator
# Using a TCL while loop, keep iterating over the layers until there are no more to iterate over.
while {[$Iterator SclIterateNext SwaHandle] == $SCL_TRUE} {
# Write the layer name to the message window by inquiring the SwaHandle reference variable using the SclGetId command.
puts "Layer name is [$SwaHandle SclGetId]"
# store the layername into a variable called "layerName"
set layerName [$SwaHandle SclGetId]
# Don't store the main graphics layer into the list of selectable layers as it may be empty.
if {$layerName != "main graphics layer"} {
# Append the layerName into a list called layerList. TCL lists are simple. Just imagine a shopping list.
lappend layerList $layerName
}
}
puts "Layers added to a list... Click in Graphics to continue"
SclPause
# Form definition start here. Details of the form are stored in the "layerSelection" variable.
set layerSelection {
#GuidoForm container has two switches, the label and default_buttons switch.
GuidoForm form {
-label "Select Layer"
-default_buttons
GuidoComboBox layer {
-label "Layer"
-width 15
-exclusive true
-default "design"
}
}
};# Form definition ends here.
# Use the SclCreateGuidoForm command to compile the form into a variable called "formH"
SclCreateGuidoForm formH $layerSelection {
# This populates the combobox with all the layers in the layerList variable
set layer.setValues $layerList
}
$formH SclRun {}
if {"$_status" != "apply"} {
puts "Macro cancelled"
# Normally you would stop the macro if someone pressed cancel but in our example we press on. Just unhash return for normal function. "return" is another TCL command that in this instance will stop the macro.
#return
}
puts "You have selected the \"$layer\" layer"
sclGraphicsLayers SclIterateFirst Iterator
# ourSwa is the reference variable that we can use when setting the active layer
while {[$Iterator SclIterateNext ourSwa] == $SCL_TRUE} {
# store the layername into a variable called "layerName"
set layerName [$ourSwa SclGetId]
# Check to see if the current layer stored in $layerName is the one selected which is stored in $layer variable.
if {$layerName == $layer} {
puts "Active layer is now $layer. Check the \"layers\" pane to see if this is true."
# If we find the required layer, use the SclSetActiveLayer command to change the active layer referenced by $SwaHandle
$vh SclSetActiveLayer $ourSwa
puts "Click in graphics once layer is confirmed."
SclPause
# no need to search once we have found the layer we are after. Break will exit the while loop.
break
}
}
puts "End of part 3"
####### PART 4 #######
puts ""
puts "Part 4 - Saving a layer then recalling data into a created layer before modifying."
#Saving a layer can be done with a normal recorded "Save Layer" or "Save File" function however SCL provides a way to do it as well.
#Depending on which layer you chose in part 3 will depend on which layer will now be saved.
# This will get the date into a format that the string file header can use
set today [clock format [clock seconds] -format "%d %b %Y"]
#Options variable is a set of parameters separated by the | symbol. Some of the options are styles, binary or text and string range.
set options "header=$layer, $today, Test of SclSwaSaveStringFile, ssi_styles:styles.ssi|axis=0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0|binary=off"
# This is the line of code that will save a string file with your included options.
$ourSwa SclSwaSaveStringFile $layer.str "$options"
#Let's assume we have saved the data we want and need to exit graphics to start another project.
SclFunction "EXIT GRAPHICS" {}
#Now, let's recall your saved string file into a new layer we will call new_design
# Get a reference to the active viewport (You can have more than one) store it in reference variable "vh"
SclGetActiveViewport vh
# Create a layer called new_design that can be manipulated/inquired with the "newDesignSwa" reference variable
SclCreateSwa newDesignSwa "new_design"
# Add the new_design layer into the layers pane so it is visible
sclGraphicsLayers SclAdd $newDesignSwa $vh
# Everything in "" is an option. The option to "load draw styles" will ensure the styles file is used.
$newDesignSwa SclSwaOpenFile $layer.str "load draw styles"
# Make the "new_design" layer active.
$vh SclSetActiveLayer $newDesignSwa
# Get a handle to all the strings in the new_design layer
$newDesignSwa SclGetStrings newDesignStrs
# Draw all the strings in graphics
$newDesignStrs SclDraw
# Whenever you bring data into a layer, you'll generally need to zoom all to see it.
SclFunction "ZOOM ALL" {}
# Now, lets say we wanted to edit a point in the layer to a known coordinate. We first need to get a "handle" to the point.
# We will use "SclSelectPoint" to achieve this. This is a very versatile function that I'll cover in a later QA doco.
# There are many options for editing this point however for this QA I will just move the point 1m East for every click on the point.
# To do this we need to put the command in a while loop.
while {1} {
# Note pointMod below. This is the reference variable that gives me complete access to this point and all data attached to it.
# Note also that the coordinates of the point are stored in the x, y and z variables below as well.
set status [SclSelectPoint pointMod "Click a point to move by 1m East. Press Esc to continue." layerName strNum segNum pntNum x y z desc]
# Using the handle we have to the point in reference variable "pointMod" get a handle to the segment it resides in.
$pointMod SclGetParent segMod
if {$status != "$SCL_OK"} {
puts "Finished moving points"
break
}
# Add 1m to the current x value
$pointMod SclSetValueByName x [expr $x+1]
$segMod SclErase
# Using the handle to the segment, draw the updated coords on the screen.
$segMod SclDraw
}
puts "End of part 4"
# At this point you could exit or save the modifications. We will leave the modified layer in graphics ready for Part 5 of this series.
# Part 5 will cover how to use SCL to loop over all points in a layer.
